GuiXT (SAP R/3) - Koehn Consulting, Lyss

Checking the date field

A date field entry needs to be reformatted and checked at the same time

You have defined your own date field by means of the “Inputfield" command. You would like this field to behave as far as possible like SAP Standard "Date"-type field. In other words :

You would like to be able to select a date with F4.
If you enter a date manually, after ENTER the field should be converted into the standard dd.mm.yyyy form
If the date is entered in a wrong form, an error message should be issued
If the date is invalid, an error message should be generated

To be able to select a date with F4, you must still specify in the input field the additional searchhelp="GuiXT.DATE" option. See also in this respect the documentation relating to the "InputField" command.

Using the script below, you can carry out the entire checking/conversion

// Script for checking the date format of an entry field
// 14.06.2004 / Gérald Koehn / Koehn Consulting / www.guixt.ch
// 
// ************************************************************
// Test of various possible forms
if not V[Datum]     // Date has not yet been attended to
goto Ende
endif
// In the third place a dot?
set V[k] &V[Datum](3-3)
if V[k=.]
// in 5th place also a dot ?
  set V[k] &V[Datum](6-6)
  if V[k=.]
// in 3rd place and 6th place a dot, so with this almost everything is OK
// Is the year four digits or two ?

set V[k] &V[Datum](9-10)  
      if not V[k]    // Enter year as two digits only
  // Now we can recompose the date
  // Now you have to decide whether 1900 or 2000
  // from 00 to 50  => 2000
  // from 51 to 99  => 1900
        set V[k] &V[Datum](7-8)
        if V[k<51]
          set V[Datum_neu](1-6) "&V[Datum]"
          Set V[Datum_neu](7-8) "20"
          Set V[Datum_neu](9-10) "&V[Datum](7-8)"
        else
          set V[Datum_neu](1-6) "&V[Datum]"
          Set V[Datum_neu](7-8) "19"
          Set V[Datum_neu](9-10) "&V[Datum](7-8)"
        endif
      else           // Year 4 digits  
  // here we do not need to do anything at all
      Set V[Datum_neu] "&V[Datum]"       
      endif      // Jahreszahl
  else    // not dot in the 6th position  => Format not valid  
  Return "E: Please enter date in form __.__.____ " -Statusline
  endif  
else     // no dot in the third position
// // so that there is also no dot in the 5th position
  Set V[k] &V[Datum](5-5)
  if V[k=.]
    Return "E: Please enter date in form __.__.____ " -Statusline
  else   // an 3 und 6 Stelle kein Punkt
    set V[Datum_neu](1-2) "&V[Datum](1-2)"
    set V[Datum_neu](3-3) "."
    set V[Datum_neu](4-5) "&V[Datum](3-4)"
    set V[Datum_neu](6-6) "."
// Is year 4 digits or only 2?
    set V[k] &V[Datum](7-8) 
    if not V[k]    // Enter year as only two digits
   // Now we can recompose the date
  // Now you have to decide whether 1900 or 2000
 // from 00 to 50  => 2000
  // from 51 to 99  => 1900
      set V[k] &V[Datum](5-6)
        if V[k<51]
          set V[Datum_neu](7-8) "20"
          set V[Datum_neu](9-10) "&V[Datum](5-6)"
        else
          set V[Datum_neu](7-8) "19"
          set V[Datum_neu](9-10) "&V[Datum](5-6)"
        endif
    else             // Year 4 digits
      set V[Datum_neu](7-10) "&V[Datum](5-8)"
    endif
  endif

endif
// Now you could check whether the date is actually valid
set V[Datum_Kontr] &V[Datum_neu] + 1
set V[Datum_Kontr] &V[Datum_Kontr] - 1
if not V[Datum_Kontr=&[Datum_neu]]        
  Return "E: The date entered is not valid !" -Statusline
else
//Assignment of converted field to the original field
  Set V[Datum] "&V[Datum_neu]"
endif
Label Ende
Return

You can build this script into a script you create yourself, first of all using the include "Datumstest.txt" command. Your script should start with the command On "Enter" Process="Ihr_Script.txt" .