GuiXT (SAP R/3) - Koehn Consulting, Lyss

Delete selections

Using GuiXT, you can initialise all selection fields (including multiple selection)

With the following input script, you can initialise all entry fields for a selection screen.
For example, if a multiple selection is also entered by selecting a variant, this too is deleted.

In line with the transaction where this script is used, the coordinates of the individual elements may still have to be adjusted. The number of lines has been limited to 100. If a selection screen should, however, have more than 100 entry fields, you can simply increase the value of 100. It is also possible to include the script in an existing input script as Include.
(Preferably at the beginning)

// Input script to delete the selection field of any selection screen
// 27.01.2010 / Gérald Koehn / Koehn Consulting / www.guixt.ch
// Script was developed for transaction IW49;
// for other transactions, certain coordinates may need to be adjusted

// “FROM field” and “TO Field” and the multiple selection are looped through all screen elements

Set V[z]  4        // Line
Set V[sv]  34      // FROM column may have to be adjusted according to transaction
Set V[sb]  59      // TO column may have to be adjusted according to transaction
Set V[sm]  78      // Multiple selection column may have to be adjusted according to transaction

Label Selektion_new_Screen
Screen *
  Label Selektion_loeschen
  // limited to 100 lines, should in normal circumstances suffice; 
  // can, however, easily be increased
  if V[z<100]
    GetFieldattribute  #[&[z],&[sm]] buttonicon="Icone"
    if V[Icone=1E]   // then there is one more multiple selection which should also be deleted
      SetCursor #[&[z],&[sv]]
      Enter "DELA"
      Set #[&[z],&[sv]] ""       // Delete FROM field
      Set #[&[z],&[sb]] ""       // Delete TO field
      set V[z] &[z] + 1
      goto Selektion_new_Screen
    else
      Set #[&[z],&[sv]] ""       // Delete FROM field
      Set #[&[z],&[sb]] ""       // Delete TO field
      set V[z] &[z] + 1
      goto Selektion_loeschen
    endif   
  else
    Enter
  endif