GuiXT (SAP R/3) - Koehn Consulting, Lyss

Menuführung

Menubedienung anstatt Easy Access

Wenn Sie Anwender haben, welche sehr wenige Funktionalität von SAP benötigen, so können Sie Ihren Anwendern anstatt einer Menuführung über Easy Access eine Menuführung mittels Drucktasten zur Verfügung stellen.

Durch das Drücken der Taste Spez. Menu wird in dieses Menu umgeschaltet.

Screenshot SAP Standard Menu

Mit dem Klick auf die Taste SAP Standard Menu kann man jederzeit wieder auf das Easy Access wechseln.

Durch einen Klick auf die Taste Materialwirtschaft kommt man ins Untermenu der Materialwirtschaft.

Screenshot Materialwirtschaft

Durch einen Klick auf Stammdaten kommt man auf die unterste Stufe des Menus. Hier befinden sich jetzt die eigentlichen Aufrufe der Transaktionen.

Screenshot Stammdaten

Mit dem Knopf

kommt man im Menu jeweils wieder eine Stufe zurück.

Die zur Verfügung gestellten Scripts beinhalten derzeit ein zweistufiges Menu. Es ist jedoch so konzipiert, dass Sie x-beliebig Stufen definieren können. Mehr als 4 Stufen erachten wir dann jedoch nicht als sinnvoll.

saplsmtr_navigation.d0100.txt

// Beispiel für Menuesteuerung mit GuiXT
// 02.07.2003 / Gérald Koehn / Koehn Consulting / www.guixt.ch

del M[SAP Menü]
del M[Business Workplace]
del M[Rolle anlegen]
del M[Menü einer  Rolle anzeigen]
del M[Benutzermenü]
del M[Auffrischen]
del M[Ausführen]
del M[Ausführen in neuem Fenster]
del M[Verknüpfung erstellen auf dem Desktop]
del M[Hinzufügen]
del M[Ändern]
del M[Verschieben]
del M[Löschen]
del M[Ordner einfügen]
del M[Transaktion einfügen]
del M[Sonstige Objekte einfügen]
del M[Download auf PC]
del M[Upload von PC]
del M[Information zur Administration]
del M[Benutzer zuordnen]
del M[Dokumentation anzeigen]
del M[Technische Detailinformation]
del M[Einstellungen]
del M[Starttransaktion festlegen]

if V[Menu=SP]               // Nur wenn Menue auf Spez eingestellt
del X[IMAGE_CONTAINER]
Pushbutton (Toolbar) "SAP Standard Menu"  "Process=Untermenue.txt" "Size=3" "F6"
  using SPEZ = "ST"

if not V[Untermenue] and V[Menu=SP]
  Title "Koehn Consulting"
  pushbutton (0,1) "Materialwirtschaft"  "Process=Untermenue.txt" "Size=3"
  using Untermenue = "M"
  pushbutton (4,1) "Vertrieb          "  "Process=Untermenue.txt" "Size=3"
  using Untermenue = "V"
else
  On "/15" "Process=Untermenue.txt"
  using Beenden = "X"
endif
if V[Untermenue=M]    // Menue Materialwirtschaft
  Title "Materialwirtschaft"
  pushbutton (0,1) "Stammdaten        "  "Process=Untermenue.txt" "Size=3"
  using Untermenue = "MS"
  pushbutton (4,1) "Bestände          "  "Process=Untermenue.txt" "Size=3"
  using Untermenue = "MB"
endif

if V[Untermenue=MS]    // Materialwirtschaft Stammdaten
  Title "Materialwirtschaft Stammdaten"
  pushbutton (0,1) "Material anlegen  "  "/NMM01" "Size=3"
  pushbutton (4,1) "Material ändern   "  "/NMM02" "Size=3"
endif
else                   // Kein Spez. Menue

Pushbutton (Toolbar) "Spez. Menu" "Process=Untermenue.txt" "Size=3" "F7"
  using SPEZ = "SP"

endif

untermenue.txt

// Beispiel für Menuesteuerung mit GuiXT
// 02.07.2003 / Gérald Koehn / Koehn Consulting / www.guixt.ch
Parameter Untermenue
Parameter Beenden
Parameter SPEZ
// Falls SP übergeben wird, so soll auf das SpezialMenu umgeschaltet werden
if U[SPEZ=SP]
   set V[Menu] "SP"
   Return
endif
// Falls ST übergeben wird, so wird auf SAP Standard Menu umgeschaltet
if U[SPEZ=ST]
   set V[Menu] " "
   set V[Untermenue] " "
   Return
endif
// Handling des Zurücksringens auf Menu der nächsten Stufe
if U[Beenden=X]  and V[Untermenue]  // Jetzt soll aus einem Untermenue zurückgesprungen werden
// Über diesen Loop wird festgestellt, auf welcher Ebene, dass man sich befindet
  set V[i] 1
  set V[Stufenzähler] 0
  Label Loop
  set V[M_Stufe] "&V[Untermenue](&[i]-&[i])"
  if V[M_Stufe]
     set V[Stufenzähler] &V[Stufenzähler] + 1
     set V[i] &V[i] + 1
     goto Loop
  else          // höchste Stufe + 1 erreicht
     set V[Stufenzähler] &V[Stufenzähler] - 1
     if V[Stufenzähler=0]   // Wir sind schon auf der Stufe 1 deshalb nur zurücksetzen der Variable V[Untermenue]
       set V[Untermenue] " "
       Return
     else
       set V[Untermenue] "&V[Untermenue](1-&[Stufenzähler])"  // Die Variable Untermenue soll um einen String verkürzt werden
       Return
     endif
  endif
endif
// *************************** Ende Handling des Zurückspringens aus einem Menue
// Übergabe des U-Parameters an V-Variable und Return, damit Bild entsprechend der Variable V[Untermenue]
// verändert werden kann
Set V[Untermenue] "&U[Untermenue]"
Return

Download: menu.zip
(2 txt-Dateien, zip-komprimiert, 1.63 KB)