GuiXT (SAP R/3) - Koehn Consulting, Lyss - Selecting data in GRID Control

Selecting data in GRID Control

Extract the content of a GRID control into GuiXT variables

The example below is based on the VA05N transaction (customer order list). By pressing the “Select grid” button, the entire contents of the list are put into the clipboard.
Through a loop, by means of the CopyText command, each individual row and column is processed and extracted to individual variables.
The variables are built up as follows
V[VA05N_z_s] where z= row and s=column.
By means of the "Sort" command, all the data has been sorted correspondingly. For more information, see the documentation on the “Sort” command.

GuiXT Script for VA05N (saplslvc_fullscreen.0500.txt)

InputScript grid_auslesen.txt

// InputScript to select grid
// The content of the grid is transferred onto the clipboard
// The clipboard is then transferred to a long text in GuiXT
// This long text is then looped through to transfer the
// values into individual variables
// 27.11.2010 / Gérald Koehn / Koehn Consulting / www.guixt.ch

// List of Sales Orders 
Screen SAPLSLVC_FULLSCREEN.0500
  Enter "/Menu=1,4,3"      	// Local File...
  
// Save list in file... 
Screen SAPLSPO5.0110
  Set #[8,2] 	"X"         // Radiobutton X In the clipboard
  Enter 
  
Screen SAPLSLVC_FULLSCREEN.0500
    // Initialise variables and long text
  set V[VA05N_*] ""
  Set Text[VA05N_*] ""
    // Copy clipboard in long text
  CopyText ToText="VA05N_Liste" -fromclipboard
    // Extraction into the individual variables
  set V[i] 1     // Counter lines from source
  set V[z] 1     // Counter cells in individual lines
  Label VA05N_Liste_lesen
  CopyText FromText="VA05N_Liste" toString="String" Line="&[i]"
  if Q[ok]
    // now we read each individual cell of the table
    set V[z] 1
    Label Einzelne_Zelle
    CopyText FromString="String" toText="String_Einzel"
    CopyText FromText="String_Einzel" toString="String_Einzel_String" Line="&[z]" Delimiter="|"
    if Q[ok]
      set V[VA05N_&[i]_&[z]]	"&V[String_Einzel_String]"
      set V[z] &[z] + 1
      goto Einzelne_Zelle
    endif   
    set V[i] &[i] + 1
    goto VA05N_Liste_lesen
  endif
  Enter