GuiXT (SAP R/3) - Koehn Consulting, Lyss - Bezeichnung zu Mime Objekten

Bezeichnung zu Mime Objekten

Im Transportauftrag können Sie sich durch dieses Script, die Bezeichnungen zu den Mime Objekten anzeigen lassen

Wenn Sie Ihre GuiXT Objekte im SAP Mime Repository ablegen, ist Ihnen vielleicht aufgefallen,
dass im Transportauftrag der Objektname (z.B. E01EFBA6764C33F1809240618619DD1C) aufgeführt ist.
Die Bezeichung des Files ist im Transport nicht ersichtlich.
Mit untenstehendem Script können sie sich in der Tabelle der Objekte die Bezeichnung einblenden lassen.

SAPLSCTSREQ.0100.TXT

// GuiXT Script zur Anzeige der Bezeichung des Mime Objektes
// Beispiel Koehn Consulting / 09.09.2011 / Gérald Koehn
if T[SAPLSCTS_OLE_TC_OLE] 
  Tablewidth T[SAPLSCTS_OLE_TC_OLE] 180  
  // Loop zur Beschaffung der Daten zu den Objekten
  // Initialisieren der Variablen
  set V[i] 1
  set V[SAPMR_Object.*] ""
  Label Objektbezeichnungen
  set V[check_programm_id]	"&cell[SAPLSCTS_OLE_TC_OLE,TRE071X-PGMID,&[i]]"
  set V[check_objecttyp] 		"&cell[SAPLSCTS_OLE_TC_OLE,TRE071X-OBJECT,&[i]]"
  set V[check_objectname]  	"&cell[SAPLSCTS_OLE_TC_OLE,TRE071X-OBJ_NAME,&[i]]"
  set V[check_object_char] 	"&V[check_objectname]"  -charcount
  if V[check_programm_id]
    if V[check_programm_id=R3TR] and V[check_objecttyp=SMIM] and V[check_object_char=32] 
      set Text[properties] ""
      set V[object_id](SDOKOBJECT-CLASS) "M_TEXT_L"
      set V[object_id](SDOKOBJECT-OBJID) "&V[check_objectname]"
      call "SDOK_LOIO_PROPERTIES_GET" In.OBJECT_ID="&V[object_id]" table.PROPERTIES="properties"
      copyText FromText="properties" toString="text" Line="3"  
      set V[SAPMR_Object.&[i]] 	"&V[text](SDOKPROPTY-VALUE)" // DESCRIPTION 
    endif
    set V[i] &[i] + 1
    goto Objektbezeichnungen
  endif
  Columnwidth [SAPLSCTS_OLE_TC_OLE,TRE071X-OBJ_NAME] 32
  Column "&ddic[ROXABV0060-BEZEICH]" Name="SAPMR_Object" position="5" table="T[SAPLSCTS_OLE_TC_OLE]" size="40" 
endif